.PS
# Sockets.m4
log_init
include(ics.m4)

  ifelse(ifpgf(T)`'ifpstricks(T),T,`command "{\small\sf"')

 H: HDMI_micro
  "\sf Micro" rjust at H.Base.sw+(-2bp__,0) "\sf HDMI" rjust

 U: USB_C_Socket with .Base.sw at (H.e.x+0.85,H.Base.s.y)
  "\sf USB-C Socket" at U.Base.s below
  "\sf B12" at U.B12.end above ljust
  "\sf B1" at U.B1.end above ljust
  "\sf A1" at U.A1.end above rjust
  "\sf A12" at U.A12.end above rjust

 C1: connDX with .nw at H.Base.ne+(0.5,0)
  "`\sf DA15-PD'" at C1.s below

 C2: connDX(,L,type=F) with .w at C1.e+(0.6,0)
  "`\sf DA15-SD'" at C2.s below

  ifelse(ifpgf(T)`'ifpstricks(T),T,`command "}"')

thinlines_
  arrow <- from C1.T1.w left 0.25; "\sf T1" rjust
  arrow <- from C1.T8.w left 0.25; "\sf T8" rjust
  arrow <- from C1.T9.e right 0.25
  arrow <- from C1.T15.e right 0.25

  arrow <- from C2.T1.e right 0.25; "\sf T1" ljust
  arrow <- from C2.T8.e right 0.25; "\sf T8" ljust
  arrow <- from C2.T9.w left 0.25
  arrow <- from C2.T15.w left 0.25
  "\sf T9" at 1/2 between C1.T9 and C2.T9
  "\sf T15" at 1/2 between C1.T15 and C2.T15
thicklines_

.PE
